package src.game {
	
	import flash.display.Sprite;
	import flash.display.MovieClip;
	import flash.geom.Point;	
	import flash.display.Stage;
	import flash.events.MouseEvent;
	import flash.ui.Mouse;
	import flash.display.Shape;
	import flash.display.BitmapData;   
	import flash.display.Bitmap;
    import flash.display.Loader;
    import flash.net.URLRequest;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
	import src.utils.Image;
	import src.utils.ImageTile;
	
	public class TileMap extends Sprite {
		
		public var bitmap:Bitmap=new Bitmap();
		
		private var loader:Loader = new Loader();		// loads in bitmap for texturized shapes, etc
		private var bitmapData:BitmapData=null;
		private var loadedTexture:String=null;
		
		public var dat:Array=new Array();
		public var images:Array=new Array();
		
		public var tW:Number=0;
		public var tH:Number=0;
		
		public var map:Map=null;
		
		public function TileMap(map,datstr:String,vW,vH,tW,tH) {
			
			this.map=map;
			this.tW=tW;
			this.tH=tH;
			
			trace("[TileMap] Constructing.  tile Dimensions: tW, tH.  Full map dimensions: vW, vH: "+tW+" "+tH+" "+vW+" "+vH);
			
			if(datstr) {
				this.dat=datstr.split("c");
				for(i=0;i<dat.length;i++) {
					dat[i]=dat[i].split("r");		// split rows
					
					// check # of rows to see if theres enough
					while(dat[i].length<vH/tH) {
						dat[i].push(null);
					}
				}
			}
			// check # of cols to see if theres enough
			while(dat.length<vW/tW) {
				dat.push(new Array());
				for(i=0;i<vH/tH;i++) dat[dat.length-1].push(null);	// make rows within column
			}
			
			
			for(var i:int=0;i<dat.length;i++) {
				images[i]=new Array();
				for(var j:int=0;j<dat[i].length;j++) {
					if(dat[i][j]!=null && dat[i][j]!=0) {
						// theres an active tile to load in there
						trace("theres an image to load! "+dat[i][j]+" make it width: "+tW+" "+tH);
						
						images[i][j]=newImage(dat[i][j],i,j);
					}
					else images[i][j]=null;
				}
			}
		}
		
		public function newImage(sheettile,tx,ty) {
			if(!sheettile || sheettile==0 || !map.tileType[sheettile]) return null;
			
			//trace("[TileMap.as] New TileImage sheettile: "+sheettile);
			var image:ImageTile=null;					// this is the graphical representation
			image=new ImageTile(map,sheettile,tW,tH);
			image.x=tx*tW-tW/2;
			image.y=ty*tH-tH/2;
			this.addChild(image);
			//trace("[TileMap.as] newImage() created an image.  set it to x/y: "+image.x+"/"+image.y);
			return image;
		}
		
		public function refreshTile(tx,ty) {
			//trace("refreshing tile: "+tx+" "+ty);
			if(images[tx][ty]!=null) {
				this.removeChild(images[tx][ty]);
			}
			
			images[tx][ty]=newImage(dat[tx][ty],tx,ty);
		}
	}
}